PRO SWEA_L1_ENERGIES
;+
; Project     :	STEREO - IMPACT, SWEA
;
; Name        : COMPUTE_SWEA_ENERGIES
;
; Purpose     :	Calculate SWEA energy sweep values
;
; Category    :	STEREO, IMPACT, SWEA
;
; Explanation :	
;
; Syntax      :	SWEA_L1_ENERGIES
;
; Examples    :	
;
; Inputs      :	None.
;
; Opt. Inputs :	None.
;
; Outputs     :	None.
;
; Opt. Outputs:	None.
;
; Keywords    :	None
;
; Calls       :	None
;
; Common      : swea_l1_common
;
; Restrictions:	
;
; Side effects:	None.
;
; Prev. Hist. :	None.
;
; History     :	Version 1 (preliminary), 3-Feb-2006, Peter Schroeder,
;                  UC-Berkeley.
;
; Contact     :	peters@ssl.berkeley.edu
;-
;
common swea_l1_common

h = 1.746d-7
k = 6.67d
scale = 5090d
dac0 = 41448d

dac = dblarr(48)
dac[0] = dac0
for i=1,47 do dac[i] = dac[i-1] - dac[i-1] * scale / 65536d

energies = dblarr(48)
energies = k * h * dac * dac

energies_bnds = k * h * dac[1:47] * dac[0:46]
energies_dach = dac0/(1d - scale/65536d)
energies_dacl = dac[47] - dac[47]*scale/65536d
energies_bndsh = k*h*dac0*energies_dach
energies_bndsl = k*h*dac[47]*energies_dacl
energies_bnds = [energies_bndsh,energies_bnds,energies_bndsl]

denergies = dblarr(48)
denergies = energies_bnds[0:47] - energies_bnds[1:48]

swea_energies = energies

swea_denergies = denergies

swea_dist_energy = dblarr(16)
swea_dist_denergy = dblarr(16)
for i=0,15 do begin
   eindx = where(SWEA_DIST_ENERGIES eq i, ecnt)
   swea_dist_energy[i] = total(swea_energies[eindx])/ecnt
   swea_dist_denergy[i] = total(swea_denergies[eindx])
endfor

return
end